Listing of file='ACPA070C' on disk='vmedia/701-2654C.wvd.zip'
# Sector 334, program filename = 'ACPA070C'
0010 REM ACPA070C, RELEASE 1-0, (01/31/79) THIS PROGRAM IS A COPYRIGHT PRODU
CT OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBIT
ED
0020 REM PROGRAM NAME = ACPA070C
0030 REM RELEASE NUMBER = 01
0040 REM REVISION NUMBER = 00
0050 REM DATE WRITTEN = 1/12/79
0070 REM **************************************************
0080 REM * THIS PROGRAM IS PART OF A GENERALIZED *
0090 REM * APPLICATION. COPYRIGHT WANG LABS INC. 1979 *
0100 REM **************************************************
0110 REM SYSTEM NAME = GBS/MVP ACCOUNTS PAYABLE SYSTEM
0120 REM MODULE NAME = PRINT CHECK REGISTER
0130 REM PROGRAM FUNCTION = PRINTS CHECK REGISTER IN CHECK NO./VENDOR ID ORDER
0140 REM **************************************************
0150 REM
0170 COM N,Q$(2)64,Q6$64,Q7$64,Q3,Q4,Q5,Q6,Q7,Q8,Q9,M$8
0171 REM
0172 COM K$1,K6$(50)4
0173 REM
0174 COM D6(4),G6(4),N6(4)
0175 REM
0176 COM N0$(4)5,N1$(4)21,N2$(4)8,N0(4),N1(4),N2(4),N2(4),N3(4),N5$(4)1
0198 GOTO 4000
3996 REM **********************
3997 REM PRINT CHECK REGISTER *
3998 REM **********************
3999 REM
4000 Q=1
4010 LOAD T"KFAMClos"10,199 BEG 4040
4030 % ##,###,###.##-
4040 SELECT @PARTS0$
4070 REM SET-UP REPORT TYPE
4090 $UNPACK(F=HEX(A0016002A008A003))STR(M$(),57) TO K$,L0,M$,I0$
4100 PRINT HEX(03);TAB(15);"CHECK REGISTER - PRINT"
4110 REM TAG SORT LEAVES FILES OPEN IN READ-ONLY MODE
4120 DATA LOAD DC OPEN T#3,S$(3)
4130 L=L0+5
4140 REM PAGE-EJECT
4150 GOSUB 7100
4160 J=0
4170 REM READ A SET OF TAGS
4180 J = MOD(J,50) + 1
4190 IF J=1THEN DATA LOAD DC #3,K6$()
4200 IF END THEN 4470
4210 IF STR(K6$(J),1,1)=HEX(FF) THEN 4470
4220 DATA LOAD DA T#1,(STR(K6$(J),,2))M$()
4230 K1 = VAL(STR(K6$(J),3,2),2)
4240 IF STR(M$(K1),1,1)=HEX(FF) THEN 4470
4250 $UNPACK(F=HEX(A005A015A0086004620662066206A001))M$(K1)TO N0$(K1),N1$(
K1),N2$(K1),N0(K1),N1(K1),N2(K1),N3(K1),N5$(K1)
4260 L = L + 1
4270 GOSUB '90
4280 G6(4) = G6(4) + N1(K1)
4290 D6(4) = D6(4) + N2(K1)
4300 N6(4) = N6(4) + N3(K1)
4310 IF N5$(K1) = " " THEN Q9 = 0
: ELSE CONVERT N5$(K1) TO Q9
4320 Q9 = Q9 + 1
4330 IF Q9 = 4 THEN 4370
4340 G6(Q9) = G6(Q9) + N1(K1)
4350 D6(Q9) = D6(Q9) + N2(K1)
4360 N6(Q9) = N6(Q9) + N3(K1)
4370 M$()=" EXTERNAL (ITEM ON FILE) EXTERNAL
(ITEM NOT ON FILE)VOID CHECK"
4380 PRINTUSING "##### ##################### ######## ########",N0$(K
1),N1$(K1),N0(K1),N2$(K1);
4390 PRINTUSING 4030,N1(K1);
4400 PRINTUSING 4030,N2(K1);
4410 PRINTUSING 4030,N3(K1);
4420 PRINT TAB(98);STR(M$(),Q9*27-26,27)
4430 SELECT PRINT 005(80)
4440 GOTO 4180
4450 REM ------------------------
4460 REM PRINT TOTALS
4470 L = L + 6
4480 GOSUB '90
4490 M$()="CHECKS PRINTED TOTAL EXTERNAL CHECKS TOTAL (
ITEM ON FILE) EXTERNAL CHECKS TOTAL (ITEM NOT ON FILE)CHECK REGISTER T
OTAL"
4500 PRINT
4510 FOR Q9 = 1 TO 4
4520 PRINT TAB(7);STR(M$(),Q9*40-39,40);TAB(50);
4530 PRINTUSING 4030,G6(Q9);
4540 PRINTUSING 4030,D6(Q9);
4550 PRINTUSING 4030,N6(Q9)
4560 PRINT
4570 NEXT Q9
4580 SELECT PRINT 005(80)
4590 REM END OF PROGRAM
4600 DEFFN'31
4610 GOSUB '219(S$(1),1,S2," ",0)
4620 GOSUB '219(S$(3),3,S2," ",0)
4650 COM CLEAR I
4660 LOAD TM$
7000 REM ****************
7010 REM * SUBROUTINES *
7020 REM ****************
7030 REM PAGE EJECT ROUTINE
7040 DEFFN'90
7050 SELECT PRINT <I0$>(132)
7060 Q6$=" "
7070 KEYIN Q6$,7080,7080
7080 IF Q6$="P" THEN GOSUB '254
7085 IF Q6$=HEX(1F) THEN GOSUB '31
7090 IF L < L0 THEN RETURN
7100 SELECT PRINT <I0$> (132)
7110 P1 = P1 + 1
7120 PRINT HEX(0C0A0D0E);TAB(3);N2$
: REM COMPANY NAME
7130 Q6$="A/P CHECK REGISTER - SORTED BY"
7140 IF K$="1"THEN Q6$=Q6$&" CHECK NO."
: ELSE Q6$=Q6$&" VENDOR ID"
7150 PRINT TAB(45);Q6$;TAB(109);Q1$;TAB(121);"PAGE ";P1
7160 PRINT HEX(0A)
7170 PRINT " VEND VENDOR";TAB(34);"CHECK";TAB(45);"CHECK";TAB(59);"GROSS"
;TAB(75);"DISC";TAB(91);"NET"
7180 PRINT " ID NAME";TAB(37);"NO DATE";TAB(61);"AMT";TAB(76);"AM
T";TAB(91);"AMT";TAB(98);"REMARKS"
7190 PRINT HEX(0A)
7200 L = 7
7210 RETURN
9000 REM *************
9010 REM * VARIABLES *
9020 REM *************
9030 REM D6() = DISCOUNT TOTALS
9040 REM G6() = GROSS TOTALS
9050 REM N6() = NET TOTALS
9060 REM BUCKETS ==> 1 = CHECKS, 2 = 'E' PAYMENTS , 3 = 'X' PAYMENTS, 4 = REG
ISTER TOTALS
9070 REM BUCKETS IS A PEDESTRIAN WAY OF SAYING "TOTAL ACCUMULATORS!!"
9080 REM $
9999 DEFFN'29"Q$= ";HEX(22);"ACPA070C";HEX(22);":SCRATCH T Q$:SAVE T$()Q$";HEX
(0D)