image of READY prompt

Wang2200.org

Listing of file='INTEREST' on disk='vmedia/tbo_81.wvd.zip'

# Sector 863, program filename = 'INTEREST'
0010 REM INTEREST CALCULATION
0020 SELECT LIST 005(80),PRINT 005(80)
0030 PRINT HEX(0D0C030E);"Interest calculation"
0040 REM Y=YEARS  Y1=START  Y2=END Y0=INCREMENT
0050 Y1=5
   : Y2=20
   : Y0=5
0051 P1=5
   : P2=15
   : P0=1
   : R1=10
0070 PRINT "Min years =",Y1,
   : INPUT " or",Y1
0080 PRINT "Max years =",Y2,
   : INPUT " or",Y2
0090 PRINT "Years step =",Y0,
   : INPUT " or",Y0
0100 REM %0  P Principal, P1 Low amount, P2 Hi amount, P0 Amount increment
0101 PRINT "Enter amounts in thousands"
0102 PRINT "Low amount =",P1,
   : INPUT " or",P1
0104 PRINT "Hi amount =",P2,
   : INPUT " or",P2
0106 PRINT "Amount step=",P0,
   : INPUT " or",P0
0110 PRINT "Low % rate =",R1,
   : INPUT " or",R1
   : R1=R1/100
0120 REM %0  R1 Low interest rate, R2 Hi interest rate, R0 Interest increment
0125 P1=P1*1000
   : P2=P2*1000
   : P0=P0*1000
0130 R2=R1+.05
   : R0=.01
0135 H=0
   : INPUT "For hard copy Key 1 (RETURN)",H
   : IF H=0THEN 140
   : SELECT PRINT 215(132)
0138 PRINT HEX(0D0C030E);"Interest calculation"
0140 GOSUB 250
0150 % $###,###  ##.##%
0160 % ###  $####.##
0170 FOR P=P1 TO P2 STEP P0
0180 FOR R=R1 TO R2 STEP R0
0190 PRINTUSING 150,P,R*100;
0200 FOR Y=Y1TO Y2 STEP Y0
0210 I=R/12
   : N=Y*12
   : M=P*I/(1-(1+I)^(-N))
0220 PRINTUSING 160,Y,INT(100*M)/100;
0230 NEXT Y
   : PRINT
   : NEXT R
0232 KEYIN C$,233,233
   : GOTO 236
0233 GOSUB 250
   : PRINT "Pause";HEX(0D);
0234 KEYIN C$,235,235
   : GOTO 234
0235 PRINT ,,
0236 B=B+1
   : IF B<8THEN 238
   : B=0
   : IF H<>1THEN 238
0237 PRINT HEX(0D0C030E);"Interest calculation"
   : GOSUB 250
0238 PRINT
   : NEXT P
0240 GOSUB 250
   : END
0250 PRINT "  Loan     Rate  ";
0260 FOR Y=Y1TO Y2 STEP Y0
   : PRINTUSING 160,"#Yr","Pay";
   : NEXT Y
   : PRINT
0270 RETURN