Listing of file='DISKMAKE' on disk='vmedia/tbo_81.wvd.zip'
# Sector 897, program filename = 'DISKMAKE'
0010 REM DISKMAKE 04/28/78
0020 COM I,O
: DIM W1$64,M$8,A$64,B$1,C$1
0030 E$="12......9"
: REM /DISKETTES WANTED
0040 PRINT HEX(030E);"Determine size of WANG 2200 Diskette"
0050 PRINT "Modify line 30 for diskettes"
: GOSUB 150
0070 Q1=0
: INPUT "Key 1 if for Mini-floppy",Q1
0080 E=0
: PRINT "Spare sectors=";E;
: INPUT "per program file or",E
0090 GOSUB 450
: PRINT "2200 DISK PACKAGE"
0100 PRINT HEX(0E);"DISK STORAGE REQUIREMENTS--"
0110 GOSUB 150
0120 D9=349
: ON Q1GOTO 130
: D9=1023
0130 IF S<D9+1THEN 250
: PRINT "---System specified will not fit within the ";D9;" disk sectors ne
eded."
0140 PRINT "No disk created"
: STOP "--- CHANGE LINE 30 to reconfigure"
0150 PRINT " WITH CAPABILITY FOR -- "
0160 IF STR(E$,1,1)="."THEN 170
: PRINT "1= TBO PROGRAM DEVELOPMENT"
0170 IF STR(E$,2,1)="."THEN 180
: PRINT "2= TBO SECONDARY AIDS"
0180 IF STR(E$,3,1)="."THEN 190
: PRINT "3= MEMORY DIAGNOSTIC"
0190 IF STR(E$,4,1)="."THEN 200
: PRINT "4= ????????"
0200 IF STR(E$,5,1)="."THEN 210
: PRINT "5= ASYNC TC"
0210 IF STR(E$,6,1)="."THEN 220
: PRINT "6= TC DATA PREP"
0220 IF STR(E$,7,1)="."THEN 230
: PRINT "7= ????????????"
0230 IF STR(E$,9,1)="."THEN 240
: PRINT "9= GAMES"
0240 PRINT
: RETURN
0250 Q0=0
: INPUT "IF YOU WISH A DISK COPY KEY 1 ELSE (EXEC) ",Q0
0260 IF Q0=0THEN 140
0270 PRINT "From Disk Default=";I
0280 INPUT "1=(F)310 2=(R)B10 3=(F)320 4=(R)B20 5=(F)330 6=(R)B30
7=(F)350",I
0290 IF I<1 OR I>7 THEN 270
0300 PRINT "To Disk Default =";O
0310 INPUT "1=(F)310 2=(R)B10 3=(F)320 4=(R)B20 5=(F)330 6=(R)B30
7=(F)350",O
0320 IF O<1 OR O>7 THEN 270
0330 IF I<>O THEN 340
: PRINT "I/O Diskettes may not be the same"
: GOTO 270
0340 ON I SELECT #1/310;#1/B10;#1/320;#1/B20;#1/330;#1/B30;#1350
0350 ON O SELECT #2/310;#2/B10;#2/320;#2/B20;#2/330;#2/B30;#2350
0360 INPUT "Mount formatted disk on destination drive and key (EXEC)",S0
0380 PRINT "Scratching"
0390 SCRATCH DISK T#2, LS=5,END =D9
: REM ..ERR I95 denotes protected
0400 PRINT "Writing "
: GOSUB 450
0410 PRINT "Verifying"
: VERIFY T #2,(0,D9)
0420 PRINT "Modify last statements of ASKAEMUL to reflect emulators saved"
0430 GOSUB 150
: STOP "2200 diskette created"
0440 REM %FIND MODULE DESCRIPTION
0450 RESTORE
: S,B,C=0
0460 READ A$
: IF A$=" "THEN 600
: A=1
0470 C$=STR(E$,A,1)
: IF C$<>"."THEN 490
0480 A=A+1
: IF A<10THEN 470
: GOTO 460
0490 IF C$<>STR(A$,A,1)THEN 480
0500 IF Q1=0 THEN 510
: IF STR(A$,20,1)="*"THEN 480
0510 B=B+1
: PRINT
: PRINTUSING 590,B,A$;
0520 CONVERT STR(A$,12,3)TO A
: C=C+A
0530 CONVERT STR(A$,16,3)TO A
: S=S+A
0540 IF A=0 THEN 460
0550 IF Q0=0 THEN 460
0560 ON B GOTO 460
: IF STR(A$,20,1)="f"THEN 580
0570 MOVE T #1, STR(A$,21,8) TO T #2,(E)
: PRINT "moved";
: GOTO 460
0580 MOVE T #1, STR(A$,21,8) TO T #2,(0)
: PRINT "moved";
: GOTO 460
0590 %## ####################################################
0600 PRINT " ----"
0610 PRINTUSING 630,E*B
: S=S+(E*B)
0620 PRINTUSING 640,B,E$,C,S
: RETURN
0630 % ### = TOTAL SPARE SECTORS
0640 %## ######### #### ### = TOTAL SECTORS NEEDED (1ST=SOURCE) 2ND=COMPRESSE
D
0650 REM % Select disk device addresses
0660 REM % --I/O Module Description
0670 REM %.CONFIGURATION CAPABILITY
0680 REM ..123456789.SIZE CMP MODULE DESCRIPTION
0690 DATA "123456789. 005 005 DISK CATALOG INDEX AREA"
0700 DATA "123456789. 007 007 START COMMON LOGIC"
0702 DATA "..3....... 004 004 fMEM MEMORY DIAG."
0710 DATA "..3....... 003 003 f16K MEMORY DIAG."
0720 DATA "..3....... 003 003 f20K MEMORY DIAG."
0730 DATA "..3....... 003 003 f24K MEMORY DIAG."
0740 DATA "..3....... 003 003 f28K MEMORY DIAG."
0750 DATA "..3....... 003 003 f32K MEMORY DIAG."
0752 DATA "..3....... 003 003 fM1 MEMORY DIAG."
0754 DATA "..3....... 003 003 fM1.5 MEMORY DIAG."
0756 DATA "..3....... 004 004 fM2 MEMORY DIAG."
0757 DATA "..3....... 005 005 fM3 MEMORY DIAG."
0758 DATA "..3....... 004 004 fM4 MEMORY DIAG."
0760 DATA "1......... 005 005 fCROSSREF INITIAL MODULE"
0770 DATA "1......... 005 005 fCROSS16K MEM."
0780 DATA "1......... 005 005 fCROSS20K MEM."
0790 DATA "1......... 005 005 fCROSS24K MEM."
0800 DATA "1......... 005 005 fCROSS28K MEM."
0810 DATA "1......... 005 005 fCROSS32K MEM."
0820 DATA "1......... 005 005 *CROSS64K MEM."
0840 DATA "1......... 043 043 CROSSRF CROSSRF SETUP"
0850 DATA "1......... 043 043 CROSSRF0 CROSSRF (T) MAINLINE"
0860 DATA "1......... 043 043 *CROSSRFV CROSSRF (VP)MAINLINE"
0870 DATA "1......... 025 025 SORTCAT SORT DISK CATALOG"
0880 DATA "1......... 030 030 PROGCOMP PROGRAM COMPARE"
0890 DATA "1......... 033 033 PROGVERB PROGRAM SEARCH"
0895 DATA ".2........ 040 040 DISKFLOW FLOW CHARTER"
0900 DATA ".2........ 017 017 DISK MAP "
0910 DATA "1......... 010 010 DISKEXAM"
0915 DATA ".2........ 030 030 *DISKMAKE VP DISK MAKER"
0920 DATA "1......... 003 003 RENAME DATA FILE"
0930 DATA "........9. 042 042 STARTREK STAR TREK 12K"
0935 DATA "1......... 004 004 STARTN START NUMBERS"
0940 DATA "1......... 005 005 ARRAYLOC FIND ARRAY LOCATION"
0950 DATA "1......... 011 011 NUMBERS CONVERSION"
0960 DATA ".....6.... 005 005 DATAPREP LOADER FOR TC"
0970 DATA ".....6.... 022 022 BSC-CARD CARD TO TC DISK"
0980 DATA ".....6.... 034 034 BSC-KEY KEY TO TC DISK"
0990 DATA ".....6.... 017 017 BSC-LIST LIST TC DISK"
1000 DATA "....5..... 027 027 27B*TTY ASYNC TC"
1010 DATA "1......... 005 005 NOTES"
1350 DATA " "