image of READY prompt

Wang2200.org

Listing of file='CRAPS' on disk='vmedia/more_games.wvd.zip'

# Sector 470, program filename = 'CRAPS'
0010 REM CRAPS
0015 LOAD DC T#6,"GAMES"
0020 DIM C$(9),E$(9),F$(9),G$(9),I$(9)
   : C$="*********"
   : E$="* 0     *"
   : F$="*   0   *"
   : G$="*     0 *"
   : I$="* 0   0 *"
   : K$="*       *"
0030 PRINT HEX(03)
   : PRINT "WELCOME TO THE WANG CASINO."
   : PRINT
   : PRINT "THE GAME IS  -CRAPS-"
   : PRINT
   : PRINT "PRESS ANY KEY TO BEGIN GAME"
0040 A=RND(1)
   : KEYIN H$,50,50
   : GOTO 40
0050 PRINT HEX(0C);
0060 B=1000
   : P=5000
   : A=0
   : H$=" "
   : INPUT "DO YOU WISH TO REVIEW THE RULES (Y/N)",H$
   : IF H$="Y"THEN 80
   : IF H$="N"THEN 70
   : PRINT HEX(0C);TAB(64)
   : PRINT HEX(0C);
   : GOTO 60
0070 PRINT HEX(03)
   : GOTO 100
0080 PRINT HEX(03)
   : PRINT "--2,3,OR 12 ON THE FIRST ROLL LOSES-"
   : PRINT "--7 OR 11 ON THE FIRST ROLL WINS-"
   : PRINT "--ANY OTHER NUMBER BECOMES YOUR POINT-"
   : PRINT "--7 OR 11 ON SUBSEQUENT ROLLS LOSES-"
   : PRINT "--YOUR STAKE IS $1000 - LOSE IT AND YOU'RE GONE-"
0090 PRINT "--I RESERVE THE RIGHT TO CLOSE THE GAME AT ANY TIME-"
   : PRINT "--PLEASE CONTROL YOUR PROFANITY!!--"
0100 PRINT HEX(0A0A);"YOUR BANK IS $";B
0110 W=0
   : INPUT "YOUR BET",W
   : IF W>=1THEN 120
   : PRINT HEX(0C);TAB(64)
   : PRINT HEX(0C);
   : GOTO 110
0120 IF W>BTHEN 590
   : IF W=0THEN 800
   : IF W<50THEN 130
   : T=0
   : GOTO 140
0130 PRINT "PIKER!!"
   : FOR Z=1TO 300
   : NEXT Z
   : A=0
0140 PRINT HEX(03)
0150 T=0
   : GOSUB 690
   : IF T=2THEN 160
   : IF T=3THEN 170
   : IF T=12THEN 180
   : IF T=7THEN 190
   : IF T=11THEN 200
   : GOTO 210
0160 IF A>1THEN 220
   : PRINT "SNAKE-EYES!!";
   : GOTO 250
0170 IF A>1THEN 220
   : PRINT "LITTLE-JOE!!";
   : GOTO 250
0180 IF A>1THEN 220
   : PRINT "BOX-CARS!!";
   : GOTO 250
0190 IF A>1THEN 240
   : PRINT "LUCKY SEVEN!!";
   : GOTO 420
0200 IF A>1THEN 240
   : PRINT ".....AND E-LEVEN!!";
   : GOTO 420
0210 IF A>1THEN 220
   : O=T
   : GOTO 150
0220 IF T=OTHEN 230
   : GOTO 150
0230 PRINT "MADE YOUR POINT!";
   : GOTO 420
0240 PRINT "CRAPPED OUT!";
   : GOTO 250
0250 PRINT "YOU LOSE!!"
   : Y=Y+1
   : IF Y>1THEN 340
   : IF X<>0THEN 260
   : PRINT "TOO BAD!"
   : GOTO 410
0260 IF X<>1THEN 270
   : PRINT "MY TURN!"
   : GOTO 410
0270 IF X<>2THEN 280
   : PRINT "ABOUT TIME!"
   : GOTO 410
0280 IF X<>3THEN 290
   : PRINT "LOSIN' YOUR TOUCH?"
   : GOTO 410
0290 IF X<>4THEN 300
   : PRINT "FINALLY!!"
   : GOTO 410
0300 IF X<>5THEN 310
   : PRINT "BROKE THAT STREAK!!"
   : GOTO 410
0310 IF X<>6THEN 320
   : PRINT "CAN'T WIN 'EM ALL---CAN YOU?"
   : GOTO 410
0320 IF X>=7THEN 330
   : GOTO 410
0330 PRINT "ME?    SWITCH DICE?"
   : GOTO 410
0340 IF Y<>2THEN 350
   : PRINT "AGAIN"
   : GOTO 410
0350 IF Y<>3THEN 360
   : PRINT "YOU'RE DOIN' GREAT!!"
   : GOTO 410
0360 IF Y<>4THEN 370
   : PRINT "WHO'S YOUR BANKER?"
   : GOTO 410
0370 IF Y<>5THEN 380
   : PRINT "WANNA RAISE THE BET?"
   : GOTO 410
0380 IF Y<>6THEN 390
   : PRINT "YOU'RE JUST LIKE MONEY IN THE BANK!"
   : GOTO 410
0390 IF Y>=7THEN 400
   : GOTO 410
0400 PRINT "KEEP UP THE GOOD WORK!"
0410 X=0
   : B=B-W
   : P=P+W
   : FOR Z=1TO 1000
   : NEXT Z
   : PRINT HEX(03)
   : A=0
   : GOTO 620
0420 PRINT "YOU WIN!!"
   : X=X+1
   : IF X>1THEN 510
   : IF Y<>0THEN 430
   : PRINT "DARN!"
   : GOTO 580
0430 IF Y<>1THEN 440
   : PRINT "DAMN!"
   : GOTO 580
0440 IF Y<>2THEN 450
   : PRINT "THOUGHT I HAD YA THAT TIME!!"
   : GOTO 580
0450 IF Y<>3THEN 460
   : PRINT "BETCHA CAN'T DO THAT AGAIN!"
   : GOTO 580
0460 IF Y<>4THEN 470
   : PRINT "MUST BE LOSIN' MY TOUCH!"
   : GOTO 580
0470 IF Y<>5THEN 480
   : PRINT "ABOUT TIME - HUH?"
   : GOTO 580
0480 IF Y<>6THEN 490
   : PRINT "JUST WHEN I WAS GOIN'GREAT!"
   : GOTO 580
0490 IF Y>=7THEN 500
   : GOTO 580
0500 PRINT "YOU WIN?"
   : GOTO 580
0510 IF X<>2THEN 520
   : PRINT "GETCHA NEXT TIME!"
   : GOTO 580
0520 IF X<>3THEN 530
   : PRINT "DON'T I HEAR YOUR MOTHER CALLIN'?"
   : GOTO 580
0530 IF X<>4THEN 540
   : PRINT "KNOCK THAT OFF!!";
   : GOTO 580
0540 IF X<>5THEN 550
   : PRINT "HAVE A HEART, FELLA!"
   : GOTO 580
0550 IF X<>6THEN 560
   : GOTO 680
0560 IF X<>7THEN 570
   : PRINT "ONCE MORE AND I QUIT!!"
   : GOTO 580
0570 IF X>7THEN 610
0580 Y=0
   : B=B+W
   : P=P-W
   : FOR Z=1TO 1000
   : NEXT Z
   : PRINT HEX(03)
   : A=0
   : GOTO 620
0590 N=N+1
   : IF N<>1THEN 600
   : PRINT "NO CREDIT AT THIS TABLE!!"
   : GOTO 100
0600 IF N<>2THEN 610
   : PRINT "THAT'S TWICE, ASSHOLE!  DON'T DO IT AGAIN!!"
   : GOTO 100
0610 PRINT "I WARNED YOU SHIT-HEAD!!"
   : FOR Z=1TO 500
   : NEXT Z
   : GOTO 660
0620 IF B=0THEN 630
   : IF P=0THEN 640
   : GOTO 100
0630 PRINT "YOU LOST IT ALL!!"
   : GOTO 650
0640 PRINT "YOU'VE BUSTED THE BANK!  CONGRATULATIONS!!"
   : GOTO 800
0650 PRINT "NEXT PLAYER"
   : FOR Z=1TO 400
   : NEXT Z
   : GOTO 30
0660 PRINT HEX(03)
   : PRINT TAB(26);"---"
   : PRINT TAB(25);"*****"
   : PRINT TAB(25);"*****"
   : PRINT TAB(25);"*****"
   : PRINT TAB(25);"*****"
   : PRINT TAB(18);"-   -  *****  -"
   : PRINT TAB(17);"*** *** ***** *** **"
   : PRINT TAB(16);"*   *   *     *   *  *"
   : PRINT TAB(16);"*   *   *     *   *   *"
   : PRINT TAB(16);"*                      *"
0670 PRINT TAB(16);"*                     *"
   : PRINT TAB(17);"*                  *"
   : PRINT TAB(17);" *               *"
   : PRINT TAB(19);"*              *"
   : PRINT TAB(19);"****************"
   : FOR Z=1TO 2000
   : NEXT Z
   : GOTO 20
0680 PRINT HEX(03)
   : FOR Z=1TO 15
   : PRINT TAB(INT(59*RND(1)));"SHIT!"
   : NEXT Z
   : GOTO 580
0690 PRINT HEX(03)
   : IF A<1THEN 700
   : GOTO 710
0700 PRINT "FIRST ROLL:"
   : A=A+1
   : GOTO 720
0710 PRINT "YOUR POINT IS";O
   : A=A+1
0720 J=J+1
   : IF J>2THEN 790
   : D=INT(6*RND(1)+1)
   : T=T+D
   : R=INT(54*RND(1)+1)
   : IF D=1THEN 730
   : IF D=2THEN 740
   : IF D=3THEN 750
   : IF D=4THEN 760
   : IF D=5THEN 770
   : IF D=6THEN 780
0730 PRINT TAB(R);C$
   : PRINT TAB(R);K$
   : PRINT TAB(R);F$
   : PRINT TAB(R);K$
   : PRINT TAB(R);C$
   : GOTO 720
0740 PRINT TAB(R);C$
   : PRINT TAB(R);E$
   : PRINT TAB(R);K$
   : PRINT TAB(R);G$
   : PRINT TAB(R);C$
   : GOTO 720
0750 PRINT TAB(R);C$
   : PRINT TAB(R);E$
   : PRINT TAB(R);F$
   : PRINT TAB(R);G$
   : PRINT TAB(R);C$
   : GOTO 720
0760 PRINT TAB(R);C$
   : PRINT TAB(R);I$
   : PRINT TAB(R);K$
   : PRINT TAB(R);I$
   : PRINT TAB(R);C$
   : GOTO 720
0770 PRINT TAB(R);C$
   : PRINT TAB(R);I$
   : PRINT TAB(R);F$
   : PRINT TAB(R);I$
   : PRINT TAB(R);C$
   : GOTO 720
0780 PRINT TAB(R);C$
   : PRINT TAB(R);I$
   : PRINT TAB(R);I$
   : PRINT TAB(R);I$
   : PRINT TAB(R);C$
   : GOTO 720
0790 FOR Z=1TO 500
   : NEXT Z
   : J=0
   : RETURN
0800 END