image of READY prompt

Wang2200.org

Listing of file='MATCHES' on disk='vmedia/games.wvd.zip'

# Sector 730, program filename = 'MATCHES'
0100 REM ***23 MATCHES
0105 PRINT HEX(03)
0110 PRINT "LET'S PLAY 23 MATCHES. WE START WITH 23 MATCHES."
0115 PRINT "YOU MOVE FIRST. YOU MAY TAKE 1,2, OR 3 MATCHES."
0120 PRINT "THEN I MOVE ... I MAY TAKE 1,2, OR 3 MATCHES."
0125 PRINT "YOU MOVE, I MOVE AND SO ON. THE ONE WHO HAS TO"
0130 PRINT "TAKE THE LAST MATCH LOSES."
0135 PRINT "GOOD LUCK AND MAY THE BEST COMPUTER (HA,HA) WIN"
0139 STOP "(KEY CONTINUE, RETURN/EXEC)"
0140 FOR L=1TO 500
   : NEXT L
0150 M=23
0160 PRINT HEX(030A)
0200 REM ***THE HUMAN MOVES
0205 PRINT
0210 PRINT "THERE ARE NOW";M;"MATCHES."
0215 PRINT
0220 PRINT  "HOW MANY DO YOU TAKE"
0230 INPUT H
0240 IF H>M THEN 510
0250 IF H<>INT(H) THEN 510
0260 IF H<=0 THEN 510
0270 IF H>=4 THEN 510
0280 M=M-H
0290 IF M=0 THEN 410
0295 PRINT HEX(030A0A)
0300 REM ****THE COMPUTER MOVES
0305 IF M=1 THEN 440
0310 R=M-4*INT(M/4)
0320 IF R<>1 THEN 350
0330 C=INT(3*RND(0))+1
0340 GOTO 360
0350 C=(R+3)-4*INT((R+3)/4)
0360 LET M=M-C
0370 IF M=0 THEN 440
0375 PRINT
0380 PRINT "I TOOK";C;"....."
0390 GOTO 210
0410 PRINT
0420 PRINT "I WON!!!BETTER LUCK NEXT TIME"
0430 GOTO 140
0440 PRINT
0450 PRINT "O.K. SO YOU WON. LETS PLAY AGAIN"
0460 GOTO 140
0510 PRINT  "YOU CHEATED! BUT I'LL GIVE YOU ANOTHER CHANCE"
0520 GOTO 215
0999 END
1000 DEFFN'31
   : LOAD DC F"GAMES"