image of READY prompt

Wang2200.org

Listing of file='DIGD010A' on disk='vmedia/702-0079.wvd.zip'

# Sector 163, program filename = 'DIGD010A'
0010 REM .    DIGD010A,    00-00 (08/19/75),    12002
0100 DIM R$17,A$12,A1$12,X(3),Y(3),M$64
   : INIT(0A)R$
   : STR(R$,1,1)=HEX(01)
   : GOSUB '115("DATA ENTRY",1)
   : PRINT HEX(010A);"PLACE CURSOR ON ACTIVE AREA OF TABLET",TAB(64)
   : GOSUB 1780
   : PRINT HEX(010A),TAB(64),TAB(64),TAB(64)
0210 PRINT STR(R$,1,10);TAB(10);"TESTING",TAB(41);"RESULT"
   : PRINT TAB(10);"INPUT A ......................... ";
   : J,K=0
   : SELECT INPUT 25A,CO 05A
   : INPUT A
   : FOR I=1TO 25
   : A1=A
   : SELECT INPUT 25A,CO 05A
   : INPUT A
   : SELECT INPUT 001,CO 005
   : IF K=0THEN 350
   : GOSUB '31(A,A1)
0350 K=1
   : NEXT I
   : GOSUB '33(J)
   : PRINT TAB(10);"DATA LOAD BT (N=12)/65A,A$ ...... ";
   : J,K=0
   : FOR I=1TO 25
   : A1=A
   : DATA LOAD BT(N=12)/65A,A$
   : IF POS(A$=0D)<>12THEN 520
   : IF NUM(A$)<>11THEN 520
   : IF STR(A$,1,3)<> "-00"THEN 520
   : IF K=0THEN 530
   : CONVERT STR(A$,1,11)TO A
0500 GOSUB '31(A,A1)
   : GOTO 540
0520 J=1
0530 K=1
0540 NEXT I
   : GOSUB '33(J)
   : PRINT TAB(10);"DATA LOAD /65A,A ................ ";
   : J,K=0
   : DATA LOAD /65A,A
   : DATA LOAD /65A,A
   : FOR I=1TO 25
   : A1=A
   : DATA LOAD /65A,A
   : IF K=0THEN 670
   : GOSUB '31(A,A1)
0670 K=1
   : NEXT I
   : GOSUB '33(J)
   : PRINT TAB(10);"DATA LOAD /65A,A$ ............... ";
   : J,K=0
   : DATA LOAD /65A,A$
   : FOR I=1TO 25
   : A1$=A$
   : DATA LOAD /65A,A$
   : IF K=0THEN 810
   : CONVERT A$TO A
   : GOSUB '31(A,A1)
0810 K=1
   : NEXT I
   : GOSUB '33(J)
   : PRINT TAB(10);"INPUT A$ ........................ ";
   : J,K=0
   : SELECT INPUT 25A,CO 05A
   : INPUT A$
   : FOR I=1TO 25
   : A1=A
   : SELECT INPUT 25A,CO 05A
   : INPUT A$
   : SELECT INPUT 001,CO 005
   : CONVERT A$TO A
   : IF K=0THEN 980
   : GOSUB '31(A,A1)
0980 K=1
   : NEXT I
   : GOSUB '33(J)
   : PRINT HEX(010A);"ENTER  1 TO RE-RUN OR KEY RETURN(EXEC) TO CONTINUE"
   : KEYIN A$,1050,1050
1050 INPUT A$
   : IF A$= "1"THEN 100
   : GOSUB 1920
   : PRINT STR(R$,1,6)
   : PRINTUSING 1200,"SIGN","FLAG","X COORDINATE","Y COORDINATE"
1120 PRINT HEX(010A);"DIGITIZE POINT (FLAG 4 = CONTINUE)"
   : PRINT "? -";HEX(08);
   : DATA LOAD BT(N=12)/65A,A$
   : IF STR(A$,2,1)= "4"THEN 1240
   : PRINT STR(R$,1,7)
   : PRINTUSING 1200,STR(A$,1,1),STR(A$,2,2),STR(A$,4,4),STR(A$,8,4)
1200 %  ####     ####    ############   ############
1210 GOTO 1120
1240 GOSUB '115("ALIGNMENT",2)
   : PRINT HEX(010A);"PLACE AN ACCURATE 45 DEGREE RIGHT TRIANGLE ON THE DIGITI
     ZER"
   : GOSUB 1780
   : X(1),X(2),X(3),Y(1),Y(2),Y(3)=0
   : FOR I=1TO 4
1310 PRINT HEX(010A);"ALIGNMENT TEST - PASS";I;TAB(64)
   : FOR J=1TO 3
   : PRINT HEX(010A0A);"DIGITIZE POINT NUMBER";J,TAB(64)
   : PRINT HEX(09092D08);
   : DATA LOAD BT(N=12)/65A,A$
   : CONVERT STR(A$,4,4)TO X
   : CONVERT STR(A$,8,4)TO Y
   : X(J)=X(J)+X
   : Y(J)=Y(J)+Y
   : NEXT J
   : NEXT I
1440 PRINT STR(R$,1,11);TAB(5);"THE DIFFERENCE BETWEEN DELTA X AND DELTA Y IS"
     ;
   : PRINT ABS((Y(2)-Y(1)+X(3)-X(2))/4)
   : PRINT HEX(0A);TAB(10);"THE ACCEPTABLE RANGE IS FROM 0 TO 1"
   : PRINT HEX(010A);TAB(64),TAB(64),TAB(64)
1480 PRINT HEX(010A);"ENTER  1 TO RE-RUN OR KEY RETURN(EXEC) TO END"
   : KEYIN A$,1500,1500
1500 INPUT A$
   : IF A$= "1"THEN 1240
   : GOSUB 1920
   : PRINT HEX(0A0A);"   END OF PROGRAM"
   : PRINT HEX(0A0A);" SF. 15  -- ISS PERIPHERIAL DIAGNOSTIC MENU"
   : STOP
1570 DEFFN'33(J)
   : IF J=1THEN 1610
   : PRINT "O.K."
   : RETURN
1610 PRINT "FAILED"
   : RETURN
1650 DEFFN'115(M2$,M)
   : SELECT PRINT 005(64),CO 005(64)
   : GOSUB 1920
   : PRINT STR(R$,1,6);TAB(8);"+-----------------------------------------+"
   : PRINT TAB(8);"!    2262 X-Y DIGITIZER ";M2$;TAB(43);"TEST   !"
   : IF M=1THEN 1730
1710 PRINT TAB(8);"!       DIGITIZER SET TO POINT MODE       !"
   : GOTO 1740
1730 PRINT TAB(8);"! DIGITIZER SET TO UNSWITCHED STREAM MODE !"
1740 PRINT TAB(8);"+-----------------------------------------+"
   : RETURN
1780 PRINT "KEY RETURN(EXEC) TO RESUME",TAB(64)
   : KEYIN A$,1800,1800
1800 INPUT A$
   : RETURN
1840 DEFFN'31(B,B1)
   : A2=ABS(B-B1)
   : IF A2>1E4THEN 1890
   : A2=A2-INT(A2/1000)*1000
   : IF A2<2THEN 1900
1890 J=1
1900 RETURN
1920 PRINT HEX(03);"2200 HARDWARE DIAGNOSTIC - DIGITIZER ---------------------
     ------"
   : PRINT HEX(0A0A0A0A0A0A0A0A0A0A0A0A0A0A);"DIAGNOSIC MENU ; KEY 'RESET' AND
      SF'31";HEX(010A)
   : RETURN
1940 DEFFN'31
   : LOAD DC F "START"
1960 STOP