image of READY prompt

Wang2200.org

Listing of file='IDS2PIX5' on disk='vmedia/701-2717B.wvd.zip'

# Sector 386, program filename = 'IDS2PIX5'
1000 REM "IDS2PIX5" - APPLICATION SECURITY MODULE (USER ID & PASSWORD ENTRY)
1002 COM F1$(L)F
   : DIM F8$(6)83,E6$1
   : E6$=R8$
   : PRINT AT(23,0,);
   : IF F6$(17)<"^"THEN SELECT @PART"IDS2SUBM"
   : GOSUB 2000
   : LIMITS T#2,"ids2f005",A,B,C,D
   : DATA LOAD DA T#2,(A)F8$()
   : LIMITS T#2,"IDS2f005",A,B,C,D
1050 B=LEN(STR(E1$()))/56
   : E1$(B)="IDS2f005"&HEX(02)&BIN(LEN(STR(E1$()))/56,2)&STR(F8$(),403,1)&STR(
     F8$(),405,42)&BIN(A,2)
   : UNPACK(####)STR(E1$(B),13)TO C
   : STR(E1$(B),13,2)=BIN(C,2)
   : STR(E1$(B),19,2)=STR(E1$(B),48)
   : J1=0
   : IF R4$=" "THEN 1090
   : IF R4$=STR(E$(),75,3)AND VER(STR(E$(),74,1),"H")=1AND R8$>=STR(E$(),74,1)
     AND STR(E$(),78,8)=" "THEN 1540
1080 IF STR(E$(),75,3)=" "AND VER(STR(E$(),74,1),"H")=1AND R8$>=STR(E$(),74,1)
     AND STR(E$(),78,8)=" "THEN 1540
1090 GOSUB '32("IDS2sI04")
   : GOSUB '37(1)
   : GOSUB '37(2)
   : IF STR(E$(),78,8)=" "THEN PRINT HEX(060F);AT(14,47);"Not used"
   : IF R4$=" "THEN 1250
   : F6$(14)="N"
   : R8$="F"
   : GOSUB '41("IDS2f005",R4$,0)
   : F6$(14)="Y"
   : R8$=" "
   : IF Q=0THEN 1250
   : GOSUB '45(3,R4$)
   : GOSUB '45(4,STR(F$(),19))
   : GOSUB '45(5,F$(1))
   : GOSUB '45(6,STR(F$(),3))
   : GOSUB '45(7,F$(2))
   : R8$=E$
1230 PRINT HEX(060F);AT(11,47);"accepted"
   : GOTO 1480
1250 F6$(13)="N"
1260 GOSUB '34(3)
1300 F6$(14)="N"
   : R8$="F"
   : GOSUB '41("IDS2f005",E$,0)
   : F6$(14)="Y"
   : R8$=" "
   : IF Q<>0THEN 1360
   : J1=J1+1
   : F0$="User identification code "&HEX(22)&E$&HEX(22)&" is not in the securi
     ty file."
   : GOSUB '35(F0$)
   : IF J1<3THEN 1260
   : GOTO 1640
1360 GOSUB '45(4,STR(F$(),19))
   : GOSUB '45(5,F$(1))
   : GOSUB '45(6,STR(F$(),3))
   : GOSUB '45(7,F$(2))
   : R8$=E$
1400 GOSUB '34(8)
   : IF F=8THEN 1420
   : R4$=E$
   : FOR I=3TO 7
   : GOSUB '45(I," ")
   : NEXT I
   : E$=R4$
   : R4$,R8$=" "
   : GOTO 1300
1420 IF E$=STR(F$(),34,8)THEN 1480
   : J1=J1+1
   : GOSUB '35("User's password was not correct - Please re-enter")
   : F6$(13)="Y"
   : IF J1=3THEN 1640
   : GOTO 1400
1480 R4$=STR(F$(),31,3)
   : IF STR(E$(),78,8)=" "THEN 1531
   : F6$(13)="N"
   : J1=0
1500 GOSUB '34(9)
   : IF E$=STR(E$(),78,8)THEN 1531
   : J1=J1+1
   : GOSUB '35("Application password is not correct - Please re-enter")
   : IF J1<3THEN 1500
   : GOTO 1640
1531 IF R8$>=STR(E$(),74,1)THEN 1534
   : GOSUB '35("User class is not authorized to run this application")
   : GOTO 1640
1534 IF STR(E$(),75,3)=" "OR R4$=STR(E$(),75,3)THEN 1540
   : GOSUB '35("Another user has exclusive rights to this applications")
   : GOTO 1640
1540 STR(F6$(),11,4)="YYYY"
   : CONVERT STR(E$(),245,2)TO Q
   : IF R2$=" "THEN R2$=E4$
   : IF R2$=" "THEN R2$=@E1$
   : GOSUB '77(STR(E$(),131,8))
   : IF R2$=" "THEN GOSUB '77("IDS2P006")
   : MAT SEARCHE1$()<9>,>HEX(0F)TO F9$STEP 56
   : IF F9$<>HEX(0000)THEN GOSUB '77("IDS2PIX7")
   : F0$=STR(R3$(),,9)
   : R3$()=STR(R3$(),10)
   : IF STR(F0$,,4)="IDS2"THEN D=2
   : ELSE D=4
1630 LOAD T#D,STR(F0$,,8)1000,
1640 IF STR(E$(),139,8)=" "THEN STOP "File access error -- no recovery module
     has been programmed"
   : ELSE LOAD T#4,STR(E$(),139,8)1000,
   : END
   : LOAD T#4,STR(E$(),139,8)1000,
2000 F0$="IDS2fsXX"
   : CONVERT (R0-#PART)/16+1TO STR(F0$,7,2),(##)
   : IF F0$="IDS2fs00"THEN STOP "Invalid System File specs : Special Edit File
     "#
   : IF F0$="IDS2fs00"THEN GOTO 2000
2010 LIMITS T#2,F0$,A,B,C,D
   : @E2$(1)=BIN(A+3,2)
   : IF A=0THEN 2020
   : LIMITS T#2,"IDS2f000",A,B,C,D
   : @E2$(2)=BIN(A,2)
   : IF A=0THEN 2020
   : LIMITS T#2,"IDS2fs01",A,B,C,D
   : @E2$(3)=BIN(A+3,2)
   : IF A=0THEN 2020
   : RETURN
2020 PRINT HEX(0607020402000E);AT(23,0);"Error message:   Invalid Device Selec
     tion for IDEAS System Files ";HEX(010F05)
   : F5$=STR(E$(),139,8)
   : IF F5$=" "THEN STOP "No file provided to load"
   : GOSUB '39(F5$,4)
   : IF A=0THEN STOP "File to load does not exist"
   : LOAD T#P,F5$1000,
2050 DEFFN'77(F0$)
   : X=LEN(STR(R3$()))-9
   : MAT COPY -R3$()<,X>TO -R3$()<10,X>
   : STR(R3$(),,9)=F0$
   : RETURN