Listing of file='INVT080A' on disk='vmedia/701-2616C.wvd.zip'
# Sector 383, program filename = 'INVT080A'
0010 REM INVT080A, RELEASE 2.0, (06/01/79) THIS PROGRAM IS A COPYRIGHT PRODUCT
OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0020 REM ---------------------------------------------------------------------
--
0030 REM SYSTEM & MODULE = GBS/MVP INVENTORY SYSTEM, PHYSICAL VARIANCE REPO
RT
0040 REM PROGRAM FUNCTION = PRINT VARIANCE BETWEEN PHYSICAL AND RECORDED COU
NT
0050 REM DATE WRITTEN = 08/21/78 MK
0060 REM LAST REVISION = 08/12/79 MK
0070 REM ---------------------------------------------------------------------
--
0170 DIM A6$1,A7$8,B6$1
0198 GOTO 4000
3996 REM **************************************
3997 REM ! PHYSICAL INVENTORY VARIANCE REPORT !
3998 REM **************************************
3999 REM
4000 SELECT @PART S0$
4004 LIMITS T#3,S$(3),Q6,Q7,Q8
: REM CHECK SORT TAGS FILE
4006 Q6$="Physical inventory sheets have not been printed."&HEX(07)
4008 IF Q8<3 THEN 4304
: REM NO RECORDS IN TAG FILE?
4010 GOSUB '93(" ")
: REM IS PRINTER AVAILABLE?
4020 IF I0$=" " THEN 4450
: REM DID WE GET THE PRINTER?
4030 PRINT AT(3,0,80);HEX(07);"If update is chosen, this program should no
t be interrupted."
4040 GOSUB '100("Y,N","YyNn",1,1,"DO YOU WANT INVENTORY BALANCES UPDATED (
Y OR N)",2)
4050 A6$=Q6$
4060 GOSUB '100("Y,N","YyNn",1,1,"DO YOU WANT TO LIST ONLY PRODUCTS WITH V
ARIANCES (Y OR N)",2)
4070 B6$=Q6$
4080 GOSUB '235(1,0)
: REM FIND FIRST PRODUCT
4090 GOSUB '91
4100 IF J0=7 THEN 4000
4110 IF J0>0 THEN 4320
4120 PRINT AT(5,0);"Processing product ID ";HEX(06)
4130 REM %PROCESS RECORD
4140 GOSUB '52(2)
: REM READ PRODUCT RECORD
4150 PRINT AT(5,23,Q0);F1$
4160 IF H5$<HEX(80) THEN 4280
: REM SKIP IF NOT ON SHEETS
4170 A7$=" "
4180 IF F5>0 AND E0=0 THEN A7$="NO COUNT"
4190 IF B6$="N" THEN GOSUB 6280
: ELSE IF E0<>F5 THEN GOSUB 6280
4200 IF A6$="N" THEN 4280
: REM SKIP UPDATE?
4210 H0=Q1
: REM LAST ACTIVITY DATE
4220 E=E+E0-F5
: REM UPDATE ON HAND AMOUNT
4230 E0,F5=0
4240 AND (H5$,7F)
: REM SET CYCLE BACK TO NORMAL
4250 DBACKSPACE #2,1S
4260 GOSUB '42(2)
: REM REWRITE PRODUCT RECORD
4270 REM FIND NEXT
4280 GOSUB '237(1,0)
4290 IF Q$=" " THEN 4140
4300 IF Q$="E" THEN 4350
4302 Q6$=" "
4304 PRINT AT(1,0);Q6$
4310 GOSUB '91
4320 GOSUB '254
4330 GOSUB '31
4340 REM %CLEAR SORT TAGS FILE, PRINT TOTALS, RETURN TO MENU
4350 L=L+6
4355 IF Q$="E" AND A6$="Y" THEN GOSUB '218(S$(3),3," ",0)
4360 GOSUB '90
4370 PRINT HEX(0A0A0A)
4380 PRINT "ON HAND VALUE TOTAL";TAB(25);
4390 PRINTUSING 6260,C7
4400 PRINT "PHYSICAL VALUE TOTAL";TAB(25);
4410 PRINTUSING 6260,C6
4420 PRINT "VARIANCE VALUE TOTAL";TAB(25);
4430 PRINTUSING 6260,C6-C7
4435 REM PRINTUSING 6260,C7-C6
4440 REM %END OF PROGRAM
4450 DEFFN'31
4460 LOAD TM$
6000 REM %^SUBROUTINES
6010 REM PAGE-EJECT ROUTINE
6020 DEFFN '90
6030 SELECT PRINT 005(80)
6040 Q6$=" "
6050 KEYIN Q6$,6060,6060
: REM OPERATOR INTERRUPT CHECK
6060 IF Q6$="P" THEN GOSUB '254
6070 IF Q6$=HEX(1F) AND A6$="N" THEN GOSUB '31
6080 SELECT PRINT <I0$>(132)
6090 IF L<L0 THEN RETURN
: REM LINE COUNT CHECK
6100 P1=P1+1
6110 PRINT HEX(0C0A0E);TAB(3);N2$
: REM COMPANY NAME
6120 Q6$="NO UPDATE"
6130 IF A6$="Y" THEN Q6$=STR(Q6$,3)
6140 Q6$=Q6$&" OPTION"
6150 Q7$="PHYSICAL INVENTORY"
6160 IF B6$="Y" THEN Q7$=Q7$&" VARIANCE"
6170 Q7$=Q7$&" REPORT"
6180 PRINT Q6$;TAB(66-LEN(Q7$)/2);Q7$; TAB(110);Q1$;TAB(122);"PAGE";P1
6190 PRINT
6200 PRINT TAB(56);"ON HAND";TAB(68);"PHYSICAL";TAB(81);"QUANTITY";TAB(96)
;"AVERAGE";TAB(109);"COST"
6210 PRINT "PRODUCT ID";TAB(15);"DESCRIPTION";TAB(40);"U/M";TAB(45);"LOC";
TAB(55);"QUANTITY";TAB(68);"QUANTITY";TAB(81);"VARIANCE";TAB(98);"COST";T
AB(107);"VARIANCE";TAB(122);"REMARKS"
6220 PRINT
6230 L=3
6240 RETURN
6250 REM %PRINT DETAIL LINE
6260 %##,###,###.##-
6270 % ##,###,###-
6280 GOSUB '90
6290 PRINT F1$;TAB(Q0+3);STR(F2$,,MIN(36-Q0,LEN(F2$)));TAB(41);F3$;TAB(45)
;I5$;TAB(51);
6300 PRINTUSING 6270,F5;
6310 PRINT TAB(64);
6320 PRINTUSING 6270,E0;
6330 PRINT TAB(77);
6340 PRINTUSING 6270,E0-F5;
6341 REM PRINTUSING 6270,F5-E0;
6350 PRINT TAB(90);
6360 PRINTUSING 6260,F;
6370 PRINT TAB(103);
6380 Q8=ROUND((F5*F,2)
6390 Q9=ROUND((E0*F,2)
6400 PRINTUSING 6260,Q8-Q9;
6401 REM PRINTUSING 6260,Q9-Q8;
6410 PRINT TAB(122);A7$
6420 L=L+1
6430 C6=C6+Q9
6440 C7=C7+Q8
6450 SELECT PRINT 005(80)
6460 RETURN
9000 REM %^VARIABLES
9010 REM A6$ = UPDATE FILE (Y OR N)
9020 REM A7$ = 'NO COUNT' MESSAGE
9030 REM B6$ = ALL/VARIANCE ONLY OPTION
9040 REM C6 = PHYSICAL VALUE TOTAL
9050 REM C7 = ON HAND VALUE TOTAL
9060 REM N6$ = UPDATE ? (Y/N)
9070 REM $
9998 DEFFN'29"Q$=";HEX(22);"INVT080A";HEX(22);":SCRATCH TQ$:SAVET$()Q$";HEX(0D
)
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
"GBS/MVP - Physical inventory variance report.";HEX(22);":SELECT#15<I0$>:
$OPEN#15:SELECTLIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':$CLOSE#
15:SELECTLIST005(80)";HEX(0D)