image of READY prompt

Wang2200.org

Listing of file='INVT060D' on disk='vmedia/701-2616C.wvd.zip'

# Sector 333, program filename = 'INVT060D'
0010 REM INVT060D, RELEASE 2.0, (06/01/79) THIS PROGRAM IS A COPYRIGHT PRODUCT
      OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0020 REM ---------------------------------------------------------------------
     ---
0030 REM SYSTEM & MODULE   =  GBS/MVP INVENTORY SYSTEM, PHYSICAL INVENTORY SHE
     ETS
0040 REM PROGRAM FUNCTION  =  USE SORT TAGS TO PRINT PHYSICAL INVENTORY SHEETS
0050 REM DATE WRITTEN      =  08/13/78 MK
0060 REM LAST REVISION     =  08/12/79 MK
0070 REM ---------------------------------------------------------------------
     ---
0170     COM K$1,K6$(50)4,K5$6,K6$1
0198     GOTO 4000
3996 REM **************************
3997 REM ! PRINT PHYS INVT SHEETS !
3998 REM **************************
3999 REM
4000     SELECT @PARTS0$
4010     K6$=STR(M$(),31)
   : REM SAVE CYCLE SELECTED
4020     L,L0=VAL(STR(M$(),32))
4030     K5$=HEX(00)
4040     K$=STR(M$(),30)
   : REM REPRINT?
4050     M$=STR(M$(),241,8)
   : REM SAVE MENU NAME
4060     PRINT HEX(03);TAB(15);"PRINT PHYSICAL INVENTORY SHEETS"
4070     DATA LOAD DC OPEN T#1,S$(1)
   : REM RE-OPEN INVENTORY FILE
4080     LIMITS T#1,L9,Q9,Q9
   : REM FIND BEGINNING SECTOR
4090     DATA LOAD DC OPEN T#4,S$(4)
   : REM RE-OPEN OUTPUT FILE
4100     SELECT PRINT <STR(M$(),19,3)>(90)
   : REM SELECT PRINTER
4110     GOSUB 6090
   : REM PRINT TOP OF PAGE
4120 REM %PROCESS TAG FILE, AND INVENTORY FILE
4130     J,L6=0
4140     J=MOD(J,50)+1
4150     IF J=1THEN DATA LOAD DC #4,K6$()
   : REM READ A SET OF TAGS
4160     IF END  THEN 4350
   : REM CHECK FOR END OF FILE
4170     IF STR(K6$(J),,1)=HEX(FF) THEN 4350
4180     DBACKSPACE #1,BEG
4190     DSKIP #1,(VAL(K6$(J),2)-L9)S
   : REM POSITION TO READ PRODUCT
4200     GOSUB '52(1)
   : REM READ INVENTORY FILE
4210     DBACKSPACE #1,1S
4220     F5=E
4230     OR (H5$,80)
   : REM UNDERLINE MEANS 'PRINTED'
4240     IF K$="N" THEN GOSUB '42(1)
   : REM UPDATE PHYSICAL ON HAND
4250     IF K5$<>I5$AND K5$<>HEX(00) THEN L=L0
   : REM LOC CODE BREAK = NEW PAGE
4260 REM %PRINT DETAIL LINE
4270     GOSUB '90
4280     K5$=I5$
4290     Q6$=ALL("-")
4292     L6=L6+1
4294     PRINTUSING "#####",L6;
4300     PRINT TAB(6);F1$;TAB(Q0+8);STR(F2$,,MIN(36-Q0,LEN(F2$)));TAB(46);F3$;
     TAB(50);I5$;TAB(58);STR(Q6$,,10);TAB(75);STR(Q6$,,10)
4310     PRINT HEX(0A)
4320     L=L+2
4330     GOTO 4140
4340 REM %END OF FILE
4350     GOSUB 6200
4360     PRINT HEX(0C)
4370 REM %END OF PROGRAM
4380     DEFFN'31
4390     GOSUB '219(S$(1),1,S2," ",0)
   : REM CLOSE INVENTORY FILE
4400     GOSUB '219(S$(4),4,S2," ",0)
   : REM CLOSE SORTWORK FILE
4410     COM CLEAR I
4420     LOAD TM$
   : ERRORLOAD T"SYS MENU"
6000 REM %^SUBROUTINES
6010 REM %PAGE EJECT ROUTINE
6020     DEFFN'90
6030     Q6$=" "
6040     KEYIN Q6$,6050,6050
   : REM OPERATOR INTERRUPT CHECKK
6050     IF Q6$="P" THEN GOSUB '254
6060     IF Q6$=HEX(1F) THEN GOSUB '31
6070     IF L < L0-4 THEN RETURN
   : REM LINE COUNT CHECK
6080     GOSUB 6200
6090     P1 = P1 + 1
6100     PRINT HEX(0C0A);TAB(14);N2$
   : REM COMPANY NAME
6110     Q6$=" "
6120     IF K6$>" " THEN Q6$=" - CYCLE "&K6$
6130     PRINT TAB(24);"PHYSICAL INVENTORY SHEETS";Q6$;TAB(64);Q1$;TAB(74);"PA
     GE ";P1
6140     PRINT HEX(0A)
6150     PRINT "ITEM";TAB(6);"PRODUCT ID";TAB(Q0+8);"DESCRIPTION";TAB(45);"U/M
     ";TAB(50);"LOC";TAB(58);"PHYSICAL COUNT";TAB(75);"VERIFIED COUNT"
6160     PRINT HEX(0A)
6170     L = 6
6180     RETURN
6190 REM %PAGE FOOTER
6200     PRINT "COUNTED BY";TAB(14);"VERIFIED BY"
6210     Q6$=ALL("-")
6220     PRINT HEX(0A)
6230     PRINT STR(Q6$,,10);TAB(14);STR(Q6$,,10)
6240     RETURN
9000 REM %^VARIABLES
9010 REM   K5$() = POINTERS PRODUCED BY TAG SORT
9020 REM    K5$6 = LOCATION CODE - USED FOR BREAK CHECK
9022 REM      L6 = RUNNING ITEM NO. ON SHEETS
9030 REM $
9998 DEFFN'29"Q$=";HEX(22);"INVT060D";HEX(22);":SCRATCH TQ$:SAVET$()Q$";HEX(0D
     )
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
     "GBS/MVP - Print physical inventory sheets.";HEX(22);":SELECT#15<I0$>:$OP
     EN#15:SELECTLIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':$CLOSE#15:
     SELECTLIST005(80)";HEX(0D)