Listing of file='INVT050A' on disk='vmedia/701-2616C.wvd.zip'
# Sector 277, program filename = 'INVT050A'
0010 REM INVT050A, RELEASE 2.0, (06/01/79) THIS PROGRAM IS A COPYRIGHT PRODUCT
OF WANG LABORATORIES INC. UNAUTHORIZED REPRODUCTION OR USE IS PROHIBITED
0020 REM ---------------------------------------------------------------------
--
0030 REM SYSTEM & MODULE = GBS/MVP INVENTORY SYSTEM, LOW STOCK/INACTIVE ITE
MS
0040 REM PROGRAM FUNCTION = LIST INVENTORY ITEMS TO DELETE OR REORDER
0050 REM DATE WRITTEN = 08/11/78 MK
0060 REM LAST REVISION = 08/12/79 MK
0070 REM ---------------------------------------------------------------------
--
0170 DIM C6$1,C6$(2)21,C7$13,D6$8
0198 GOTO 4000
3996 REM ***********************************
3997 REM ! LOW STOCK/INACTIVE ITEMS REPORT !
3998 REM ***********************************
3999 REM
4000 SELECT @PARTS0$
4010 GOSUB '93(" ")
: REM IS PRINTER AVAILABLE?
4020 IF I0$=" " THEN 4500
: REM DID WE GET THE PRINTER?
4030 C6$(1)="LOW STOCK REPORT"
4040 C6$(2)="INACTIVE ITEMS REPORT"
4050 REM %ACQUIRE REPORT TYPE
4060 L=L0
4065 PRINT AT(4,0,);TAB(10);"OPTIONS AVAILABLE ==> "
4070 PRINT ,"0 = RETURN TO MENU"
4080 PRINT ,"1 = ";C6$(1)
4090 PRINT ,"2 = ";C6$(2)
4100 GOSUB '100("0","2",1,0,"ENTER OPTION DESIRED",1)
4110 IF Q6$=HEX(1F) THEN GOSUB '31
4120 C6$=Q6$
4130 IF Q9=0 THEN 4500
4140 PRINT HEX(03);TAB(24);C6$(Q9)
4150 IF Q9=1 THEN 4280
4160 REM %ACQUIRE CUTOFF DATE
4170 GOSUB '100(" ","^",8,0,"ENTER CUTOFF DATE (MM/DD/YY)",2)
4180 IF Q6$=HEX(1F) THEN GOSUB '31
4190 GOSUB '121(Q6$)
4200 IF Q6$<>"E" THEN 4230
4210 PRINT AT(3,0);HEX(07);"Invalid date, re-enter."
4220 GOTO 4170
4230 GOSUB '123(U9)
4240 D6=U9
4250 D6$=U9$
4260 PRINT AT(4,0);"Cutoff date = ";D6$;TAB(40);D6
4270 REM %FIND FIRST
4280 PRINT AT(5,0);"Processing product ID ";HEX(06)
4290 GOSUB '235(1,0)
4300 GOSUB '91
4310 IF J0=7 THEN 4060
4320 IF J0>0 THEN 4500
4330 GOSUB '52(2)
4340 PRINT AT(5,23,Q0);F1$
4350 REM %PRINT REPORT
4360 C7$=" "
4370 IF C6$="2" AND H0<=D6 THEN GOSUB 6230
: REM INACTIVE ITEM
4380 IF E+E1-E3<E4 THEN C7$="BELOW MINIMUM"
4390 IF E-E3<=0 THEN C7$="OVERALLOCATED"
4400 IF E<=0 THEN C7$="OUT OF STOCK"
4410 IF C6$="1" AND C7$>" " THEN GOSUB 6230
: REM LOW STOCK
4420 REM %FIND NEXT
4430 IF J0=7 THEN GOSUB '92
4440 GOSUB '237(1,0)
4450 IF Q$="E" THEN 4060
4460 GOSUB '91
4470 IF J0=7THEN 4430
4480 IF J0=0 THEN 4330
4490 REM %END OF PROGRAM
4500 DEFFN'31
4510 IF J0>0 THEN GOSUB '254
4520 LOAD TM$
6000 REM %^SUBROUTINES
6010 DEFFN'90
6020 SELECT PRINT 005(80)
6030 Q6$=" "
6040 KEYIN Q6$,6050,6050
: REM OPERATOR INTERRUPT CHECK
6050 IF Q6$="P" THEN GOSUB '254
6060 IF Q6$=HEX(1F) THEN GOSUB '31
6070 SELECT PRINT <I0$>(132)
6080 IF L<L0 THEN RETURN
: REM LINE COUNT CHECK
6090 P1=P1+1
6100 PRINT HEX(0C0A0E);TAB(3);N2$
: REM COMPANY NAME
6110 IF C6$="2" THEN PRINT "CUTOFF DATE ";D6$;TAB(55);C6$(2);
: ELSE PRINT TAB(58);C6$(1);
6120 PRINT TAB(110);Q1$;TAB(122);"PAGE ";P1
6130 PRINT HEX(0A)
6132 Q6$="RECMND"
6134 Q7$="REORDER"
6136 IF C6$="2" THEN Q6$,Q7$=" "
6140 PRINT TAB(47);"ON";TAB(64);"NET";TAB(83);"ON";TAB(88);Q6$;TAB(109);"L
AST"
6150 PRINT "PRODUCT ID";TAB(Q0+2);"DESCRIPTION";TAB(39);"U/M";TAB(46);"HAN
D";TAB(54);"ALLOC";TAB(63);"AVAIL";TAB(70);"MINIMUM";TAB(81);"ORDER";TAB(
88);Q7$;TAB(97);"VENDOR";TAB(107);"ACTIVITY";TAB(116);
6160 IF C6$="1"THEN PRINT "REMARKS";
6170 PRINT
6180 PRINT HEX(0A)
6190 L=7
6200 RETURN
6210 REM %PRINT DETAIL LINE
6220 %####,###-
6230 L=L+1
6240 GOSUB '123(H0)
6250 GOSUB '90
6260 PRINT F1$;TAB(Q0+2);STR(F2$,,MIN(36-Q0,LEN(F2$)));TAB(40);F3$;TAB(42)
;
6270 PRINTUSING 6220,E;
6280 PRINT TAB(51);
6290 PRINTUSING 6220,E3;
6300 PRINT TAB(60);
6310 PRINTUSING 6220,E-E3;
6320 PRINT TAB(69);
6330 PRINTUSING 6220,E4;
6340 PRINT TAB(78);
6350 PRINTUSING 6220,E1;
6360 PRINT TAB(87);
6370 IF C6$="1" AND E+E1-E3<E4 THEN PRINTUSING 6220,-INT(-MAX(B5,E5-(E+E1-
E3))/(MAX(B4,1)))*MAX(B4,1);
6380 PRINT TAB(98);G2$;TAB(107);U9$;TAB(116);C7$
6390 SELECT PRINT 005(80)
6400 RETURN
9000 REM %^VARIABLES
9010 REM C6$ = OPTION SELECTED
9020 REM D6 = JULIAN REPORT DATE
9030 REM D6$ = GREGORIAN REPORT DATE
9040 REM $
9998 DEFFN'29"Q$=";HEX(22);"INVT050A";HEX(22);":SCRATCH TQ$:SAVET$()Q$";HEX(0D
)
9999 DEFFN'30"DIM Z$57:IF STR(I0$,,1)=HEX(20)THENI0$=HEX(323135):Z$=";HEX(22);
"GBS/MVP - Low stock/inactive items report.";HEX(22);":SELECT#15<I0$>:$OP
EN#15:SELECTLIST<I0$>(132): LIST Z$:LIST Z$#:LIST Z$V:LIST Z$':$CLOSE#15:
SELECTLIST005(80)";HEX(0D)