image of READY prompt

Wang2200.org

Listing of file='ISS.080U' on disk='vmedia/701-2423D.wvd.zip'

# Sector 537, program filename = 'ISS.080U'
0010 REM  ISS.080U, RELEASE 5-1, (11/07/79) - COPYRIGHT WANG LABS. INC.
0049 COM Z9$8,Z8$8,Z1$(25)8,Z2$(25)8,Z3$(25)1,Z8,Z9,I1$,I2$,A8,O$7
   : DIM Z$(3)83,Z1$3,E$50
   : DIM M$8,D$32
0120 %   THIS MUST BE STATEMENT 120
0240 S1$="ISS.200SISS.254SISS.050S"
   : LOAD DC T#0,<LEN(S1$)/8>S1$10,0BEG 270
0270 GOSUB '50(8)
   : $UNPACK(F=HEX(A003A003A008A0075003))Z$(Z1)TO I1$,I2$,M$,O$,A8
   : GOSUB '60("PROGRAM COMPARE",5)
   : GOSUB '61("INPUT ADDRESS ONE",I1$,"80","DISK")
   : GOSUB '61("INPUT ADDRESS TWO",I2$,"81","DISK")
   : GOSUB '61("MODE",M$,"82"," ")
   : GOSUB '61("OUTPUT DEVICE",O$,"83"," ")
0360 GOSUB '62("ERROR LIMIT",A8,"84")
0380 GOSUB '70
   : GOSUB '44
   : IF O$="PRINTER"AND P$="P"THEN 540
   : SELECT #1<I1$>
   : SELECT #2<I2$>
   : GOSUB '42(M$,2)
0480 LOAD DC T#0,"ISS.081U"
   : ERRORGOTO 490
0490 PRINT AT(1,0);"RE-MOUNT ISS DISK AT ";S$;TAB(S0)
   : GOSUB '254
   : F9$="M"
   : GOTO 480
0540 PRINT HEX(010A07);"PRINTER REQUIRED"
   : GOSUB '254
   : GOTO 380
0590 DEFFN'15
   : RETURN CLEAR ALL
0610 PRINT AT(3,0,S0);
   : GOTO 380
0680 DEFFN'80
   : GOSUB '40("ENTER INPUT ADDRESS ONE")
   : Z$,I1$=Z1$
   : RETURN
0730 DEFFN'81
   : GOSUB '40("ENTER INPUT ADDRESS TWO")
   : Z$,I2$=Z1$
   : RETURN
0780 DEFFN'82
   : PRINT AT(14,0);"1 - ALL    3 - RANGE"
   : PRINT "2 - PART   4 - INDIRECT";
   : GOSUB '200("1","4",1,0,"ENTER MODE",1)
   : D$="ALL     PART    RANGE   INDIRECT"
   : Z$,M$=STR(D$,Q9*8-7,8)
   : PRINT AT(14,0,2*S0)
   : RETURN
0910 DEFFN'83
   : IF O$="CRT"THEN O$="PRINTER"
   : ELSE O$="CRT"
   : Z$=O$
   : RETURN
0970 DEFFN'84
   : Q6$="0"
   : GOSUB '200("0","999",3,0,"ENTER ERROR LIMIT (DEFAULT = 0 = PRINT ALL THE
     ERRORS)",-1)
   : A8,Z=Q9
   : RETURN
1070 DEFFN'51
   : $PACK(F=HEX(A003A003A008A0075003))Z$(Z1)FROMI1$,I2$,M$,O$,A8
   : RETURN
1130 DEFFN'42(Z9$,Z8)
   : Z9=0
   : Z8$=" "
   : IF Z9$="ALL"THEN 1260
   : IF Z9$="RANGE"THEN 1320
   : E$="MOUNT INPUT AND OUTPUT DISKS"
1190 PRINT AT(1,0);E$;TAB(S0)
   : GOSUB '254
   : IF Z9$="INDIRECT"THEN 1410
   : IF Z9$="PART"THEN 1520
   : STOP "ERROR"
1260 IF I1$=I2$THEN GOSUB '113(1,"MODE AND ADDRESSES INCOMPATIBLE")
   : Z1$(1)=ALL(HEX(00))
   : Z2$(1)=ALL(HEX(FF))
   : F9$="M"
   : RETURN
1320 IF I1$=I2$THEN GOSUB '113(1,"MODE AND ADDRESSES INCOMPATIBLE")
1330 GOSUB '200(" "," ",8,0,"ENTER BEGINNING LIMIT FOR RANGE",2)
   : Z1$(1)=Q6$
   : GOSUB '200(" "," ",8,0,"ENTER ENDING LIMIT FOR RANGE",2)
   : Z2$(1)=Q6$
   : IF Z1$(1)>=Z2$(1)THEN GOSUB '113(2,"INVALID RANGE")
   : F9$="M"
   : RETURN
1410 SELECT #3<I1$>
1430 GOSUB '200(" "," ",8,0,"ENTER REFERENCE FILE NAME",2)
   : Z8$=Q6$
   : LIMITS T#1,Z8$,Z,Z,Z,Z
   : ERRORE$="MOUNT INPUT DISK"
   : PRINT HEX(07)
   : GOTO 1190
1470 IF Z<1THEN GOSUB '113(3,"NOT AN ACTIVE FILE ON INPUT DISK")
   : IF Z=1THEN GOSUB '113(3,"WRONG FILE TYPE")
   : RETURN
1520 PRINT AT(1,0);"ENTER FILE NAMES    (0 = END)"
   : PRINT AT(10,20);"INPUT 1      INPUT 2"
   : GOTO 1630
1560 Y1=11
   : FOR Y=MAX(1,Z9-1)TO Z9
   : PRINT AT(Y1,15);Y;" ";STR(Z1$(Y),1);"     ";STR(Z2$(Y),1)
   : Y1=Y1+1
   : NEXT Y
   : PRINT HEX(0D);TAB(S0)
1630 Y1=MIN(11+Z9,13)
   : PRINT AT(Y1,0,63);
1660 PRINT AT(Y1,15);Z9+1;
   : LINPUT ?Z1$(Z9+1)
   : PRINT AT(3,0,50)
   : IF Z1$(Z9+1)="0"THEN 1900
   : LIMITS T#1,Z1$(Z9+1),Y,Y,Y,Y
   : ERRORE$="MOUNT INPUT DISK"
   : PRINT HEX(07)
   : GOTO 1190
1710 IF Y<1THEN GOSUB '113(4,"NOT AN ACTIVE FILE ON INPUT DISK")
   : IF Y=2THEN GOSUB '113(4,"NOT A PROGRAM FILE")
   : IF Z2$(Z9+1)=" "THEN Z2$(Z9+1)=Z1$(Z9+1)
1750 PRINT AT(Y1,31);
   : LINPUT Z2$(Z9+1)
   : PRINT AT(3,0,50)
   : IF I1$=I2$AND Z2$(Z9+1)=Z1$(Z9+1)THEN GOSUB '113(5,"NAMES AND ADDRESSES I
     NCOMPATABLE")
   : IF Z2$(Z9+1)="0"THEN GOSUB '113(5,"INVALID NAME")
   : LIMITS T#2,Z2$(Z9+1),Y,Y,Y,Y
   : ERRORE$="MOUNT OUTPUT DISK"
   : PRINT HEX(07)
   : GOTO 1190
1810 IF Y<1THEN GOSUB '113(4,"NOT AN ACTIVE FILE ON OUTPUT DISK")
   : IF Y=2THEN GOSUB '113(4,"NOT A PROGRAM FILE")
   : Z3$(Z9+1)=BIN(Z8+1)
   : Z9=Z9+1
   : IF Z9<25THEN 1560
1900 PRINT AT(10,0,5*S0)
   : PRINT AT(1,0,2*S0)
   : Z8=0
   : RETURN
1960 DEFFN'113(Y,E$)
   : RETURN CLEAR
1980 PRINT HEX(07);AT(3,0,50);"RE-ENTER, ";E$
   : ON YGOTO 380,1330,1430,1660,1750
2030 DEFFN'31
   : PRINT HEX(03)
   : COM CLEAR Z9$
2060 LOAD DC T#0,"ISS.100M"
   : ERRORGOTO 2070
2070 PRINT HEX(010A);"MOUNT ISS DISK AT ADDRESS ";S$
   : GOSUB '254
   : GOTO 2060