image of READY prompt

Wang2200.org

Listing of file='QUIKLIST' on disk='vmedia/701-2110C.wvd.zip'

# Sector 141, program filename = 'QUIKLIST'
0010 REM QUIKLIST 04/23/79, COPYRIGHT WANG LABORATORIES, INC. 1979
0020 DIM H$(4)64,B1$(4)62,F4$2
   : F4$=HEX(A03E)
   : DIM K$1,T$1,B$(2,255)1,T$(4),B2$(4)40,B3$32
   : INIT(2E)B3$
0035 DEFFN'15
   : SELECT PRINT 005(64),INPUT 001
   : GOSUB 730
   : GOSUB 520
0140 SELECT PRINT 005(64)
   : GOSUB 810
   : IF D=0THEN 160
   : A=A1
0160 INPUT T
   : T=INT(T)
   : IF T>3THEN 140
   : IF T=2THEN 500
0180 R,R1=0
   : IF D=0THEN 35
   : PRINT "REQUESTED LIST TYPE";T;" ";T$(T+1)
   : IF T<>2THEN 220
   : SELECT PRINT 215(120)
   : PRINT HEX(0C)
   : PRINT "***START LIST OF FILE--";F$
0210 PRINT "BLK# IMG.#--....!....1....!....2....!....3....!....4....!....5....
     !....6....!....7....!....8"
0220 INIT(00)B$()
   : GOSUB 440
   : IF D=0THEN 240
   : DATA LOAD DC #2,B1$()
   : GOTO 250
0240 DATA LOAD B1$()
0250 $PACK(F=F4$)B$()FROMB1$()
   : T$=B$(1,1)
   : R=R+1
   : IF END THEN 690
0270 % ***** BLOCK NO.=####  CARD NO.=###   RECORD LENGTH=###  *****
0280 GOSUB 400
0290 R1=R1+1
   : L=VAL(B$(1,B))
   : S,B=B+1
   : INIT(20)B2$()
   : MAT COPY B$()<B,L> TO B2$()
   : $TRAN(B3$,B2$())
   : ON T-1GOTO 620,660
   : PRINTUSING 270,R,R1,L
   : IF T=0 THEN 350
   : PRINT "BINARY RECORD DISPLAYED IN HEX"
0340 HEXPRINT B$(1,B);
   : B=B+1
   : IF B<S+LTHEN 340
   : GOTO 380
0350 K$=B$(1,B)
   : IF K$<" "THEN 360
   : PRINT K$;
   : GOTO 370
0360 PRINT "'";
   : HEXPRINT K$;
   : PRINT "'";
0370 B=B+1
   : IF B<S+LTHEN 350
0380 PRINT
   : GOSUB 430
   : IF B<B9THEN 290
   : PRINT
   : PRINT
   : IF T$<>HEX(F0)THEN 220
   : GOTO 690
0400 T$=B$(1,1)
   : B=3
   : B9=VAL(B$(1,2))
   : IF T$=HEX(00)THEN 420
   : IF T$=HEX(F0)THEN 420
0410 PRINT "IMPROPER TC FILE FORMAT "
   : GOTO 140
0420 Z=VAL(B$(1,B))
   : IF Z=0THEN 410
   : B=B+Z+1
   : IF B<B9THEN 420
   : IF B>B9THEN 410
   : B=3
   : RETURN
0430 KEYIN K$,450,450
0440 RETURN
0450 SELECT PRINT 005
   : PRINT
   : PRINT "KEY (EXEC) TO CONTINUE OR SF'0-3 TO CHANGE MODES"
0460 KEYIN K$,440,470
   : GOTO 460
0470 IF K$=HEX(1F)THEN 950
   : IF K$=HEX(0F)THEN 35
   : IF K$>HEX(03)THEN 440
   : T=VAL(K$)
   : SELECT PRINT 005(64)
   : RETURN
0480 DEFFN'0
   : T=0
   : GOTO 180
0490 DEFFN'1
   : T=1
   : GOTO 180
0500 DEFFN'2
   : T=2
   : SELECT PRINT 005
   : PRINT " OUTPUT IS TO PRINTER"
   : GOTO 180
0510 DEFFN'3
   : T=3
   : GOTO 180
0520 D=0
   : INPUT "INPUT DEVICE 1=(F)310  2=(R)B10  3=(F)320  4=(R)B20",D
   : D=INT(D)
   : IF D<1THEN 520
   : IF D>4THEN 520
   : IF D>0THEN 530
   : F$="CASSETTE"
   : RETURN
0530 PRINT "ENTER DATA FILE NAME (DEFAULT = ";F$;")";
   : INPUT F$
   : ON DGOSUB 560,570,580,590,540,550
0540 DATA LOAD DC OPEN T#2,F$
   : %FILENOTFOUND-KEYSF'15
0550 RETURN
0560 SELECT #2310
   : RETURN
0570 SELECT #2B10
   : RETURN
0580 SELECT #2320
   : RETURN
0590 SELECT #2B20
   : RETURN
0600 %#### #####--
0620 SELECT PRINT 215
   : PRINTUSING 600,R,R1;
   : IF L<=80THEN 630
   : $GIO/215(A200400D4000,P8$)B2$()<1,80>
   : PRINT "            ";
   : $GIO/215(A200400D4000,P8$)B2$()<81,L-80>
   : GOTO 640
0630 $GIO/215(A200400D4000,P8$)B2$()<1,L>
0640 SELECT PRINT 005
   : B=B+L
   : IF B<S+LTHEN 620
   : IF B<B9THEN 290
   : IF T$<>HEX(F0)THEN 220
   : SELECT PRINT 215
   : GOTO 690
0660 PRINT "BLOCK=";R,"CARD IMAGE=";R1
   : $GIO/005(A200,P8$)B2$()<1,60>
   : PRINT
   : $GIO/005(A200,P8$)B2$()<61,20>
   : PRINT
   : GOSUB 430
   : B=B+L
   : IF B<S+LTHEN 660
   : IF B<B9THEN 290
   : IF T$<>HEX(F0)THEN 220
0690 PRINT R1;" CARD IMAGES FOUND---END OF FILE ";F$
   : SELECT PRINT 005(64)
   : IF D=0THEN 695
   : GOSUB 540
   : GOTO 140
0695 PRINT "POSITIONING BEYOND END--",
   : PRINT "DONE"
   : GOTO 140
0700 DEFFN'13
   : M$="FORM FEED"
   : K$=HEX(0C)
   : GOTO 720
0710 DEFFN'14
   : M$="VERTICAL TAB"
   : K$=HEX(0B)
0720 SELECT PRINT 005
   : PRINT M$;" PRINTER"
   : SELECT PRINT 215
   : PRINT K$
   : SELECT PRINT 005
   : RETURN
0730 T$(1)="CRT IN ASCII"
   : T$(2)="CRT IN HEX   "
   : T$(3)="TO PRINTER  "
   : T$(4)="QUICK TO CRT"
   : PRINT HEX(03),,"QUICK LIST - LIST TC FILES"
0755 GOSUB 760
   : PRINT
   : PRINT "YOU MUST FIRST SELECT AN INPUT DEVICE"
   : PRINT
   : RETURN
0760 PRINT
   : PRINT "LINE PRINTER CONTROL"
   : PRINT "S.F. '13 FORM FEED,      '15 TO RESTART"
   : PRINT "S.F. '14 VERTICAL TAB,   '31 RETURN TO MAIN MENU"
   : RETURN
0810 PRINT
   : PRINT "KEY FOR LISTING -- KEY (EXEC) WILL PAUSE LIST"
   : FOR I9=1TO 4
   : PRINT TAB(5);"'";I9-1;"  ";T$(I9)
   : NEXT I9
   : RETURN
0890 DEFFN'7
   : FOR Z=1TO 120
   : HEXPRINT B$(1,Z);
   : NEXT Z
   : RETURN
   : DIM C$(4)64
0900 DEFFN'8
   : LIMITS T#2,F$,A,A9,Z
0910 DATA LOAD BA T#2,(A,A)C$()
   : PRINT "SECTOR=";A-1
   : HEXPRINT C$()
   : INPUT A
   : GOTO 910
0950 DEFFN'31
   : LOAD DC T#1,"MENU010A"